// A chain macro from Phineas

// Quick chain macro, by Phineas
// Equips the chain and use it.
// This uses control-option-click, but feel free
// to use any combination of <modifying key>-click.

control-option-click
{
        set drag_name @click.name
        "\equip \"chain\"\r"
        "\use " drag_name "\r"
}


//---------------------------------------
//---------------------------------------
//---------------------------------------
//---------------------------------------

// From Mitch Adler

// I use command-` as my chain key, change this to what you'd like.
// Very useful for runnin up to an exile and chaining with no
// muss or fuss typing.
//
// Often I just hit it multiple times near the body to be sure, chains
// grab nothing if nothing chainable is near by.
//
// Idea inspired and refined by Band and Slim.
//
command-`
   {
   set @waitCount 0 
   if @my.right_item != "chain"
      "/equip chain\r"
      label waitForChain
         if @my.right_item != "chain"
            set @waitCount + 1 
            if @waitCount < 20 
               pause 1
               goto waitForChain
            else 
               message "* Can not equip a chain." 
            end if
         end if
   end if
   
   if @my.right_item == "chain"
      "/use\r"
   end if
   }

//---------------------------------------
//---------------------------------------
//---------------------------------------
//---------------------------------------


// A Chain Macro from Noivad

// Here's a really basic chaining macro (F5). It switches to your chain
// if you aren't holding it, then it grabs whomever you've pre-selected.
// I've annotated it for those new to macros or would like to learn
// what each line does.
// 
// The only trick to using F5 and F6 is that you have time to
// command-click on the person you wish to chain. So it's best used
// when you know who you're going to chain before you enter a
// hazardous area. Or if you're really fast doing a command-click and
// F5 you can run right by with an Orga Wrath on yous ass while you
// grab that little halfling gal that just got flattened while trying to get
// out of the Orga Village area! (This actually happened just last week
// and I'm proud to say, I saved her a sure depart. It's stuff like this
// that makes learning macros so satisfying)
// 
// The Macros that follows can be cut from between the lines and
// pasted in your macro file as well:

//---------------------------------------
//The QuickChain
set rsaveitem @my.right_item
// this is a global variable since it's declared outside of a macro.
f5
{
        if @my.right_item != "Chain"
// "If I'm not holding my chain,"

                setglobal rsaveitem @my.right_item
// "remember what's in my right hand,"

                equip "Chain"
// "equip my chain,"

        end if
        pause 2
// this pause is so you can switch and chain smoothly
        "/use @selplayer.simple_name \r"
// "and chain the person I've selected."
}

//De-Equip chain
shift-f6
{
        if @my.right_item =="Chain"
                equip rsaveitem
        else
        message šNo item saved. Equipping Purse!
        equip purse
        "/narrate You notice " @my.name " running like a girl.\r"
// hehehe
        end if
}
//--------------------------------------------